# Build development version (faster, no optimizations)
build-dev:
    #!/usr/bin/env bash
    cd mlf-playground-wasm
    wasm-pack build --target web --out-name mlf_wasm --out-dir ../static/js/pkg --dev
    cd ..
    zola build

# Build release version (optimized)
build-release:
    #!/usr/bin/env bash
    cd mlf-playground-wasm
    wasm-pack build --target web --out-name mlf_wasm --out-dir ../static/js/pkg --release
    cd ..
    if command -v wasm-opt >/dev/null 2>&1; then
        wasm-opt -Oz static/js/pkg/mlf_wasm_bg.wasm -o static/js/pkg/mlf_wasm_bg.wasm
    fi
    zola build

# Start development server with live reload
serve:
    zola serve

# Zip the contents of public/ (not the folder itself) for direct upload
# to static hosts. Strips macOS junk (.DS_Store, __MACOSX resource forks).
zip:
    #!/usr/bin/env bash
    set -euo pipefail
    rm -f website.zip
    (cd public && zip -r ../website.zip . -x '*.DS_Store' '__MACOSX/*' '._*')
    echo "Wrote $(pwd)/website.zip"

# Full release: build optimized site, then zip for upload.
release: build-release zip
